Koodit: QB: Life-peli

CLS  ' Tyhjätään edellisen pelin jäänteet
RANDOMIZE TIMER  ' Satunnaisuutta peliin
DIM poista(80, 20) AS INTEGER  ' Taulukot lisättäville ja poistettaville laatikoille
DIM lisaa(80, 20) AS INTEGER

FOR i = 1 TO 100  ' Arvotaan aluksi 100 laatikkoa ruudulle (päällekäin meno on mahdollista)
  LOCATE INT(RND * 20 + 1), INT(RND * 80 + 1)
  PRINT "Û"
NEXT i

DO  ' Ohjelman päälooppi
  FOR x = 1 TO 80  ' Tyhjätään vanhat merkinnät
    FOR y = 1 TO 20
      poista(x, y) = 0
      lisaa(x, y) = 0
    NEXT y
  NEXT x

  FOR x = 1 TO 80
    FOR y = 1 TO 20
      l = 0  ' Ympäröivien laatikoiden laskurin nollaus
        ' Perässä on melkoinen hirvitys, jolla lasketaan ruutua ympäröivien laatikoiden määrä
      IF x > 1 AND y > 1 THEN
        IF SCREEN(y - 1, x - 1) = 219 THEN l = l + 1
      END IF
      IF y > 1 THEN
        IF SCREEN(y - 1, x) = 219 THEN l = l + 1
      END IF
      IF x < 80 AND y > 1 THEN
        IF SCREEN(y - 1, x + 1) = 219 THEN l = l + 1
      END IF
      IF x > 1 THEN
        IF SCREEN(y, x - 1) = 219 THEN l = l + 1
      END IF
      IF x < 80 THEN
        IF SCREEN(y, x + 1) = 219 THEN l = l + 1
      END IF
      IF x > 1 AND y < 20 THEN
        IF SCREEN(y + 1, x - 1) = 219 THEN l = l + 1
      END IF
      IF y < 20 THEN
        IF SCREEN(y + 1, x) = 219 THEN l = l + 1
      END IF
      IF x < 80 AND y < 20 THEN
        IF SCREEN(y + 1, x + 1) = 219 THEN l = l + 1
      END IF

      ' Jos ympärillä on 0,1,4 tai enemmän laatikkoa, tällä kohdalla olevat laatikot poistetaan
      IF l = 0 OR l = 1 OR l > 3 THEN
        poista(x, y) = 1
      END IF

      ' Jos ruutu on tyhjä ja sen ympärillä on tasan 3 laatikkoa, siihen luodaan uusi laatikko
      IF SCREEN(y, x) = 32 AND l = 3 THEN
        lisaa(x, y) = 1
      END IF

    NEXT y
  NEXT x

  ' Poistot ja lisäykset
  FOR x = 1 TO 80
    FOR y = 1 TO 20
      IF poista(x, y) = 1 THEN
        LOCATE y, x
        PRINT " "
      END IF
      IF lisaa(x, y) = 1 THEN
        LOCATE y, x
        PRINT "Û"
      END IF
    NEXT y
  NEXT x


SLEEP  ' Jos et halua edetä vaihe vaiheelta, poista tämä
LOOP WHILE INKEY$ <> CHR$(27)

' Täällä on ohjelman loppu, jonne tullaan kun esciä on painettu :)