Koodit: QB: Analoginen kello

CONST pii = 3.141593        ' Tarvitaan melkein jokaisessa laskussa
' Tässä perässä on sitten kaikki, mitä voit muuttaa
CONST keskix = 320          ' Kellon keskipisteen x-koordinaatti
CONST keskiy = 240          ' Kellon keskipisteen x-koordinaatti
CONST tuntipit = 75         ' Tuntiviisarin pituus
CONST minpit = 100          ' Minuuttiviisarin pituus
CONST sekpit = 100          ' Sekuntiviisarin pituus
CONST tuntivari = 15        ' Tuntiviisarin väri
CONST minvari = 15          ' Minuuttiviisarin väri
CONST sekvari = 4           ' Sekuntiviisarin väri
CONST taustavari = 0        ' Kellotaulun taustan väri
CONST vakasenvari = 15      ' Kellotaulun reunoilla olevien väkästen väri
CONST vakasenetaisyys = 110 ' Kellotaulun reunoilla olevien väkästen etäisyys keskipisteestä

SCREEN 12
CIRCLE (keskix, keskiy), minpit + 10, taustavari
DRAW "BM" + STR$(keskix) + "," + STR$(keskiy) + "P" + STR$(taustavari) + "," + STR$(taustavari)

DIM aika AS STRING

FOR i = 0 TO 59  ' Piirretään kellotaulun reunojen väkäset
  kulma = 360 / 60 * i + 180
  IF i MOD 5 = 0 THEN   ' Joka viides väkänen piirretään muita pidempänä
    LINE (-SIN(kulma * pii / 180) * (vakasenetaisyys) + keskix, COS(kulma * pii / 180) * (vakasenetaisyys) + keskiy)-(-SIN(kulma * pii / 180) * (vakasenetaisyys + 5) + keskix, COS(kulma * pii / 180) * (vakasenetaisyys + 5) + keskiy), vakasenvari
  ELSE
    LINE (-SIN(kulma * pii / 180) * (vakasenetaisyys + 2) + keskix, COS(kulma * pii / 180) * (vakasenetaisyys + 2) + keskiy)-(-SIN(kulma * pii / 180) * (vakasenetaisyys + 2) + keskix, COS(kulma * pii / 180) * (vakasenetaisyys + 2) + keskiy),  _
vakasenvari
  END IF
NEXT i

DO
  IF aika <> TIME$ THEN  ' Muutetaan kelloa vain, jos aika on muuttunut
    ' Pyyhitään vanhat viivat pois
    LINE (keskix, keskiy)-(-SIN(tuntikulma * pii / 180) * tuntipit + keskix, COS(tuntikulma * pii / 180) * tuntipit + keskiy), taustavari
    LINE (keskix, keskiy)-(-SIN(minkulma * pii / 180) * minpit + keskix, COS(minkulma * pii / 180) * minpit + keskiy), taustavari
    LINE (keskix, keskiy)-(-SIN(sekkulma * pii / 180) * sekpit + keskix, COS(sekkulma * pii / 180) * sekpit + keskiy), taustavari

    aika = TIME$
    LOCATE 25, 37
    PRINT TIME$  ' Kirjoitetaan aika myös numeroin
    tunnit = VAL(MID$(aika, 1, 2)) MOD 12  ' Otetaan tunnit, minuutit ja sekunnit
    minuutit = VAL(MID$(aika, 4, 2))
    sekunnit = VAL(MID$(aika, 7, 2))

    ' Lasketaan, missä kulmassa viisarit tulevat keskipisteeseen nähden
    tuntikulma = 360 / 12 * (tunnit + minuutit / 60) + 180
    minkulma = 360 / 60 * (minuutit + sekunnit / 60) + 180
    sekkulma = 360 / 60 * sekunnit + 180

    ' Piirretään uudet viisarit
    LINE (keskix, keskiy)-(-SIN(tuntikulma * pii / 180) * tuntipit + keskix, COS(tuntikulma * pii / 180) * tuntipit + keskiy), tuntivari
    LINE (keskix, keskiy)-(-SIN(minkulma * pii / 180) * minpit + keskix, COS(minkulma * pii / 180) * minpit + keskiy), minvari
    LINE (keskix, keskiy)-(-SIN(sekkulma * pii / 180) * sekpit + keskix, COS(sekkulma * pii / 180) * sekpit + keskiy), sekvari

  END IF
LOOP WHILE INKEY$ = ""