Koodit: QB: Mandelbrotin fraktaali

CLS
SCREEN 13
TYPE cplx                 'tyyppi komplexiluvuille
 r AS SINGLE
 i AS SINGLE
END TYPE
DIM z AS cplx
DIM a AS SINGLE
FOR pal = 0 TO 255        'paletti kuntoon
 OUT &H3C8, pal
 OUT &H3C9, 0
 OUT &H3C9, pal / 4
 OUT &H3C9, 0
NEXT pal

FOR y = -2 TO 2 STEP .02        'mandelbrot esiintyy -2 ja 2 välissä komplexiluku tasolla
 FOR x = -2 TO 2 STEP .02
  z.r = 0
  z.i = 0
  i = 1
  max = 0
  max2 = 0
  bailed = 0
  DO WHILE i <= 150 AND bailed = 0
   a = z.r
   z.r = (z.r ^ 2 - z.i ^ 2)             '\
   z.i = (a * z.i + a * z.i)             '|  mandelbrot lasketaan kaavalla Zn+1=Zn^2+c, n=alaindeksi
   z.r = z.r + x                         '|
   z.i = z.i + y                         '/
   a = (z.r ^ 2 + z.i ^ 2)
   IF a > max THEN max = a: max2 = i
   IF a >= 4 THEN bailed = 1             'jos yli 4 ei kuulu mandelbrot joukkoon
   i = i + 1

  LOOP
  IF i < 30 THEN max2 = max2 + 50        'korostetaan värejä
  PSET (x * 50 + 160, y * 50 + 100), max2
 NEXT x
NEXT y