Koodit: QB: Lopputekstit-animaatio

DECLARE SUB KeskitaAlle (teksti AS STRING)

'vieritysanimaatiotaulukko
DIM taulu(32000) AS INTEGER

'tekstitaulukko
DIM tekstit(1 TO 200) AS STRING

'rivien määrä
rivit = 58

'luetaan rivit taulukkoon
FOR i = 1 TO rivit
  READ tekstit(i)
NEXT

'320x200-grafiikkatila
SCREEN 13

'3-ulotteinen kehys
LINE (0, 0)-(319, 189), 26, B
LINE (1, 1)-(318, 188), 24, B
LINE (2, 2)-(317, 187), 22, B

'tulostetaan ensimmäinen rivi
KeskitaAlle tekstit(1)
uusi = 2
odota = 8

DO
  'siirretään näyttökuvaa yhden pikselin ylöspäin
  GET (0, 4)-(319, 100), taulu
  PUT (0, 3), taulu, PSET
  GET (0, 101)-(319, 186), taulu
  PUT (0, 100), taulu, PSET

  odota = odota - 1
  'kahdeksan välein
  IF odota = 0 THEN
    'laitetaan uusi rivi alimmaksi
    KeskitaAlle tekstit(uusi)
    uusi = uusi + 1
    odota = 8
    'jos viimeinen rivi on tulostettu, odotetaan 180 pikseliä...
    IF uusi > rivit THEN odota = 200
  ELSEIF odota = 20 THEN
    '...ja poistutaan loopista
    EXIT DO
  END IF

  'pieni viive
  WAIT &H3DA, 8
LOOP WHILE INKEY$ <> CHR$(27)

'tekstirivit pilkuilla erotettuna
DATA "ESIMERKKIPELI","-----------------","","","",""
DATA "Ohjelmointi","","Nimi1","","Nimi2","","Nimi3","","","",""
DATA "Grafiikka","","Nimi1","","Nimi2","","Nimi3","","","",""
DATA "Musiikki ja äänet","","Nimi1","","Nimi2","","Nimi3","","","",""
DATA "Testaus","","Nimi1","","Nimi2","","Nimi3",""
DATA "Nimi4","","Nimi5","","Nimi6","","Nimi7","","","",""


SUB KeskitaAlle (teksti AS STRING)
  x = 20 - LEN(teksti) \ 2
  LOCATE 23, x: PRINT teksti
END SUB