Koodit: QB: Windows-hakemistot

DECLARE FUNCTION HaeTempHakemisto$ ()
DECLARE FUNCTION HaeWindowsHakemisto$ ()
DECLARE FUNCTION HaeSysteemiHakemisto$ ()

PRINT "Windows-hakemisto: " + HaeWindowsHakemisto
PRINT "Systeemihakemisto: " + HaeSysteemiHakemisto
PRINT "   Temp-hakemisto: " + HaeTempHakemisto

FUNCTION HaeSysteemiHakemisto$
  'Ensin haetaan muuttujaan win$ Windows-hakemisto,
  'ja sitten katsotaan, onko systeemihakemisto SYSTEM32
  'vai SYSTEM

  win$ = HaeWindowsHakemisto
  IF win$ = "(tuntematon)" THEN
    HaeSysteemiHakemisto = "(tuntematon)"
    EXIT FUNCTION
  END IF
  IF DIR$(win$ + "\SYSTEM32\*.*") <> "" THEN
    sys$ = win$ + "\SYSTEM32"
  ELSEIF DIR$(win$ + "\SYSTEM\*.*") <> "" THEN
    sys$ = win$ + "\SYSTEM"
  ELSE
    sys$ = "(tuntematon)"
  END IF
  HaeSysteemiHakemisto = sys$
END FUNCTION

FUNCTION HaeTempHakemisto$
  'ympäristömuuttuja 'TEMP' tai 'TMP' sisältää
  'Temp-hakemiston nimen

  temp$ = ENVIRON$("TEMP")
  IF temp$ = "" THEN
    temp$ = ENVIRON$("TMP")
  END IF
  IF temp$ = "" THEN
    temp$ = "(tuntematon)"
  END IF
  HaeTempHakemisto = temp$
END FUNCTION

FUNCTION HaeWindowsHakemisto$
  'ympäristömuuttuja 'windir' sisältää Temp-hakemiston
  'nimen. Uusissa Windowseissa tieto saattaa olla
  'myös muuttujassa SYSTEMROOT

  win$ = ENVIRON$("windir")
  IF win$ = "" THEN
    win$ = ENVIRON$("SYSTEMROOT")
  END IF
  IF win$ = "" THEN
    win$ = "(tuntematon)"
  END IF
  HaeWindowsHakemisto = win$
END FUNCTION