Keskustelu: Koodit: QB: Pehmennys

'Pehmennä
'Tekijä: Tatu Peltola  tatu@mbnet.fi
DECLARE SUB nappain ()
DIM isox AS INTEGER, isoy AS INTEGER
DIM varit(4) AS LONG    'Tähän laitetaan värit

SCREEN 13
isox = 319: isoy = 199
RANDOMIZE TIMER
COLOR 255

'Tehdään palette!
FOR n% = 0 TO 255
        n2% = INT(n% / 4)
        c& = (n2% * &H10000) OR (n2% * &H100) OR n2%
        PALETTE n%, c&
NEXT
CLS

'Piirretään joku kuva:
FOR n% = 0 TO 199
        x% = RND * isox: y% = RND * isoy
        c& = RND * 255
        LINE -(x%, y%), c&
NEXT

PRINT "Katso minkä näköinen kuva on nyt,"
PRINT "paina jotain näppäintä ja katso miltä"
PRINT "se näyttää pehmennyksen jälkeen!"
nappain

'Pehmennetään:
pehmenna:

aloitust = TIMER
FOR x% = 0 TO isox
        FOR y% = 0 TO isoy
                varit(0) = POINT(x%, y%)
                varit(1) = POINT(x% + 1, y%)
                varit(2) = POINT(x%, y% + 1)
                varit(3) = POINT(x% - 1, y%)
                varit(4) = POINT(x% - 1, y% - 1)
                c& = 0
                FOR n% = 0 TO 4
                        IF varit(n%) = -1 THEN varit(n%) = 0
                        c& = c& + varit(n%)
                NEXT
                c& = c& / 5
                PSET (x%, y%), c&
        NEXT
NEXT
lopetust = TIMER
kuluit = lopetust - aloitust
PRINT "Kului "; kuluit; "sekuntia."
INPUT "Uusi pehmennys K/E?", K$
IF K$ = "K" OR K$ = "k" THEN GOTO pehmenna

'Lopetetaan:
END

SUB nappain
DO WHILE INKEY$ = "": LOOP
END SUB