Keskustelu: Koodit: QB: Hienosti esiin tuleva kuva

'Hienosti esiin tuleva kuva
'Tekijä: Tatu Peltola
'Saat käyttää tätä omissa ohjelmissasi.
DECLARE SUB viive ()
'***** Määritään muuttujat *****
DIM kuvankokox AS INTEGER, kuvankokoy AS INTEGER, isox AS INTEGER, isoy AS INTEGER, x AS INTEGER, y AS INTEGER
DIM n%, c$, K$
isox = 319: isoy = 199
kuvankokox = 19: kuvankokoy = 7 'kuvankokox on kuvan leveys miinus 1
                                'kuvankokoy on kuvan korkeus miinus 1
DIM kuva(kuvankokox) AS STRING
DIM naytto(&H1FF&)              'jos suurennat kuvaa niin kannattaa
                                'suurentaa myös tätä.
'**********
SCREEN 7
CLS

RESTORE kuvadata
FOR n% = 0 TO kuvankokox: READ kuva(n%): NEXT   'Luetaan kuvadata
K$ = ""
DO
FOR x = 0 TO kuvankokox
        K$ = INKEY$                             'lue nappi
        IF K$ <> "" THEN GOTO pois              'pois jos painettiin jotain

        GET (1, 0)-(isox, kuvankokoy), naytto   'luetaan näytöllä oleva kuva
        PUT (0, 0), naytto, PSET                'piirretään se eri paikkaan

        LINE (isox, 0)-(isox, kuvankokoy), 0    'tyhjennetään paikka johon
                                                'piirretään uusi kuva
        'Piirretään uusi kuva:
        FOR y = 0 TO kuvankokoy
                c$ = MID$(kuva(x), y + 1, 1)
                IF c$ = "1" THEN PSET (isox, y)
        NEXT
        'Viive:
        viive
        viive
        viive
NEXT

LOOP    'Uudestaan
pois:
END
kuvadata:
'Tässä on kuva joka piirretään. Voit laittaa tähän isommankin kuvan jos
'                                               muutat ohjelman alussa
'                                               olevia tietoja.
DATA 00000000
DATA 01111100
DATA 00010000
DATA 01111100
DATA 00000000
DATA 01111100
DATA 00000000
DATA 01111100
DATA 01010100
DATA 00000000
DATA 01111100
DATA 01000000
DATA 01111100
DATA 00000000
DATA 01111100
DATA 01000100
DATA 01111100
DATA 00000000
DATA 01111010
DATA 00000000

SUB viive
DO: LOOP UNTIL (INP(&H3DA) AND &H8) = 0
DO: LOOP UNTIL (INP(&H3DA) AND &H8) <> 0
END SUB