Keskustelu: Koodit: QB: 3D Starfield

SCREEN 13
RANDOMIZE TIMER
TYPE tahdet
x AS DOUBLE 'Kai integerkin olisi riittänyt?
y AS DOUBLE
z AS DOUBLE
END TYPE
nopeus = 1
tahtia = 100
perspective = 12
origox = 160
origoy = 100
DIM tahti(tahtia) AS tahdet
FOR g = 0 TO tahtia
tahti(g).x = INT(RND * 319) - origox
tahti(g).y = INT(RND * 199) - origoy
tahti(g).z = INT(RND * (perspective - 1)) + 1
NEXT g
DO
FOR j = 0 TO tahtia
x = tahti(j).x * perspective / tahti(j).z + origox
y = tahti(j).y * perspective / tahti(j).z + origoy
LINE (x, y)-(x + 2 - tahti(j).z / (perspective / 2), y + 2 - tahti(j).z / (perspective / 2)), 0, BF
tahti(j).z = tahti(j).z - nopeus
IF tahti(j).z <= 0 THEN
tahti(j).x = INT(RND * 319) - origox
tahti(j).y = INT(RND * 199) - origoy
tahti(j).z = perspective
END IF
x = tahti(j).x * perspective / tahti(j).z + origox
y = tahti(j).y * perspective / tahti(j).z + origoy
vari = 30 - (tahti(j).z / (perspective / 14))
LINE (x, y)-(x + 2 - tahti(j).z / (perspective / 2), y + 2 - tahti(j).z / (perspective / 2)), vari, BF
LINE (0, 0)-(319, 0), 0 'Bugin korjaus
LINE (0, 1)-(0, 199), 0
NEXT j
LOOP UNTIL INKEY$ <> ""