Keskustelu: Ohjelmointikysymykset: VB.NET: Tekstin "tulostaminen" tekstitiedostoon

Public Class Form1
    Private Sub Tallenna_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Tallenna.Click
        'Näytetään dialogi
        Dim sfd As New SaveFileDialog()
        sfd.Filter = "Tekstitiedosto (*.txt)|*.txt|Kaikki tiedostot|*.*"
        If sfd.ShowDialog() = DialogResult.OK Then
            'Tallennetaan tiedosto

            'Toimii myös näin:
            'IO.File.WriteAllText(sfd.FileName, TextBox1.Text)

            'Teksti data-taulukkoon
            Dim data() As Byte = System.Text.Encoding.UTF8.GetBytes(TextBox1.Text)

            'Salaus tulee tähän ja se tehdään data-taulukolle

            'Kirjoittaja-objekti
            Dim writer As New IO.FileStream(sfd.FileName, IO.FileMode.Create)

            'Kirjoitetaan data tiedostoon
            writer.Write(data, 0, data.Length)

            'Suljetaan virta
            writer.Close()
        End If
    End Sub

    Private Sub Avaa_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Avaa.Click
        'Näytetään dialogi
        Dim ofd As New OpenFileDialog()
        ofd.Filter = "Tekstitiedosto (*.txt)|*.txt|Kaikki tiedostot|*.*"
        If ofd.ShowDialog() = DialogResult.OK Then
            'Luetaan tiedosto

            'Toimii myös näin:
            'TextBox1.Text = IO.File.ReadAllText(ofd.FileName)

            'Lukija-objekti
            Dim reader As New IO.FileStream(ofd.FileName, IO.FileMode.Open)

            'Data-taulukko
            Dim data(reader.Length - 1) As Byte

            'Luetaan taulukkoon
            reader.Read(data, 0, reader.Length)

            'Suljetaan virta
            reader.Close()

            'Tässä kohdin salaus puretaan

            'Muutetaan vielä data tekstiksi
            TextBox1.Text = System.Text.Encoding.UTF8.GetString(data)
        End If
    End Sub
End Class