Keskustelu: Ohjelmointikysymykset: VB6: Tekstimenu VB:llä

Option Explicit

Dim Current As Label
Dim Menu As New Collection

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    Dim lngNewIndex As Long
    If KeyCode = vbKeyLeft Then
        lngNewIndex = ((Current.Tag + Menu.Count - 2) Mod Menu.Count) + 1
        Current.BackColor = vbHighlightText
        Current.ForeColor = vbHighlight
        Set Current = Menu(lngNewIndex)
        Current.BackColor = vbHighlight
        Current.ForeColor = vbHighlightText
    ElseIf KeyCode = vbKeyRight Then
        lngNewIndex = (Current.Tag Mod Menu.Count) + 1
        Current.BackColor = vbHighlightText
        Current.ForeColor = vbHighlight
        Set Current = Menu(lngNewIndex)
        Current.BackColor = vbHighlight
        Current.ForeColor = vbHighlightText
    End If
End Sub

Private Sub Form_KeyPress(KeyAscii As Integer)
    If KeyAscii = vbKeyReturn Then
        KeyAscii = 0
        MsgBox "Nykyinen valinta on " & Current.Tag
    End If
End Sub

Private Sub Form_Load()
    Dim lngA As Long
    For lngA = 0 To 4
        Menu.Add Me.Controls.Add("VB.Label", "Menu" & Menu.Count + 1)
        With Menu(Menu.Count)
            .AutoSize = True
            .Caption = vbNewLine & Space$(5) & "Valikko " & Menu.Count & Space$(5) & vbNewLine
            .BackColor = vbHighlightText
            .ForeColor = vbHighlight
            .Move 150 + .Width * lngA, 150
            .Tag = Menu.Count
            .Visible = True
        End With
    Next lngA
    Set Current = Menu(1)
    Current.BackColor = vbHighlight
    Current.ForeColor = vbHighlightText
End Sub