Keskustelu: Koodit: QB: pikselit järjestäytyvät kuvaksi

SCREEN 13

DIM piste(2999, 4) 'alustetaan

LINE (65, 68)-(282, 83), 4, B  'piiretään kuvat
LINE (63, 66)-(284, 85), 4, B
PAINT (64, 67), 12, 4
COLOR 11
LOCATE 10, 10: PRINT "Tämä kuva hajoaa pisteiksi"
SLEEP 1

FOR a = 0 TO 319   'luetaan näytöltä
FOR b = 0 TO 199
    IF POINT(a, b) <> 0 THEN 'jos pikseli ei ole musta
piste(c, 0) = a    'luetaan koordinaatit taulukkoon
piste(c, 1) = b
piste(c, 2) = -1 + RND * 2  'arvotaan suunta ja lisätään taulukkoon
piste(c, 3) = -1 + RND * 2
piste(c, 4) = POINT(a, b)   'tallentaan väri taulukkoon
c = c + 1
    END IF
NEXT b
NEXT a

c = c - 1   'vähennetään, muuten tulee yksi piste liikaa

CLS

s = 1   'asetetaan suunta
DO
FOR b = 1 TO 100
FOR a = 0 TO c   'silmukka 0 - pisteiden määrä
    PSET (piste(a, 0), piste(a, 1)), 0  'kumitetaan vanha piste
    piste(a, 0) = piste(a, 0) + piste(a, 2) * s   'siirretään piste uuteen paikaan
    piste(a, 1) = piste(a, 1) + piste(a, 3) * s
    PSET (piste(a, 0), piste(a, 1)), piste(a, 4)  'piirretään uusi piste
NEXT a
NEXT b
FOR a = 0 TO c
    PSET (piste(a, 0), piste(a, 1)), piste(a, 4)   'ja lopuksi vielä piirretään kaikki pisteet
NEXT a
a$ = INPUT$(1)  'odota näppäimen painallusta
s = -s  'vaihda suunta vastakkaiseksi
LOOP UNTIL a$ = CHR$(27)