Keskustelu: Koodit: QB: Matopeli

DECLARE FUNCTION CheckFood (direction AS INTEGER, x AS INTEGER, y AS INTEGER)
DECLARE FUNCTION CheckWall (direction AS INTEGER, x AS INTEGER, y AS INTEGER)
DECLARE SUB EndGame (score AS INTEGER)
DECLARE SUB PauseGame ()

TYPE xy
  x AS INTEGER
  y AS INTEGER
END TYPE

DIM worm(1 TO 10000) AS xy
DIM food AS xy
DIM speed AS INTEGER
DIM direction AS INTEGER
DIM length AS INTEGER
DIM score AS INTEGER
DIM growing AS INTEGER
DIM ok AS INTEGER

speed = 50
direction = 1
length = 15
score = 0
growing = 30

FOR i = 1 TO length
  worm(i).x = 100
  worm(i).y = 100 + i
NEXT i

RANDOMIZE TIMER

CLS
SCREEN 13

PRINT "Peli alkaa kun painat nappia"

DO
LOOP UNTIL INKEY$ <> ""

LOCATE 2, 1
PRINT "Peli alkaa... 2"
SLEEP (1)
LOCATE 2, 1
PRINT "Peli alkaa... 1"
SLEEP (1)
LOCATE 2, 1
PRINT "Peli alkaa... 0"
FOR i = 0 TO 1000
  WAIT &H3DA, 8
NEXT i
CLS

LINE (1, 1)-(200, 140), 4, B
LINE (50, 35)-(50, 105), 4
LINE (150, 35)-(150, 105), 4

GOSUB DrawWorm
GOSUB MakeFood

DO

  LINE (1, 1)-(200, 140), 4, B
  LINE (50, 35)-(50, 105), 4
  LINE (150, 35)-(150, 105), 4


  SELECT CASE INKEY$
  CASE CHR$(0) + CHR$(75)
    IF direction <> 2 THEN direction = 0
  CASE CHR$(0) + CHR$(72)
    IF direction <> 3 THEN direction = 1
  CASE CHR$(0) + CHR$(77)
    IF direction <> 0 THEN direction = 2
  CASE CHR$(0) + CHR$(80)
    IF direction <> 1 THEN direction = 3
  CASE CHR$(27)
    EndGame (score)
  CASE CHR$(80)
    PauseGame
  CASE CHR$(112)
    PauseGame
  END SELECT

  IF CheckFood(direction, worm(1).x, worm(1).y) = 1 THEN
    GOSUB MakeFood
    SOUND 1000, 1
    LOCATE 2, 27
    score = score + 100
    PRINT "Pisteet:"; score
    length = length + growing
  END IF

  IF CheckWall(direction, worm(1).x, worm(1).y) = 1 THEN
    EndGame (score)
  END IF

  GOSUB MoveWorm

  GOSUB DrawWorm

  FOR i = 0 TO speed
    WAIT &H3DA, 8
  NEXT i

LOOP

DrawWorm:
  PSET (worm(length).x, worm(length).y), 0
  FOR i = 1 TO 4
    PSET (worm(i).x, worm(i).y), 5
  NEXT i
  FOR i = 5 TO length - 1
    PSET (worm(i).x, worm(i).y)
  NEXT i
RETURN

MakeFood:
  tfoodx = food.x
  tfoody = food.y
  DO
    ok = 1
    food.x = INT(RND * 160) + 20
    food.y = INT(RND * 100) + 20
    FOR i = (food.x - 5) TO (food.x + 5)
      IF POINT(i, food.y) <> 0 THEN ok = 0
    NEXT i
    FOR i = (food.y - 5) TO (food.y + 5)
      IF POINT(food.x, i) <> 0 THEN ok = 0
    NEXT i
  LOOP UNTIL ok = 1
  DRAW "BM=" + VARPTR$(tfoodx) + ",=" + VARPTR$(tfoody)
  DRAW "P0,0"
  CIRCLE (food.x, food.y), 4, 8
  DRAW "P8,8"
RETURN

MoveWorm:
  FOR i = length - 1 TO 1 STEP -1
    worm(i + 1).x = worm(i).x
    worm(i + 1).y = worm(i).y
  NEXT i
  SELECT CASE direction
  CASE 0
    worm(1).x = worm(2).x - 1
  CASE 1
    worm(1).y = worm(2).y - 1
  CASE 2
    worm(1).x = worm(2).x + 1
  CASE 3
    worm(1).y = worm(2).y + 1
  END SELECT
RETURN

FUNCTION CheckFood (direction AS INTEGER, x AS INTEGER, y AS INTEGER)
  SELECT CASE direction
  CASE 0
    IF POINT(x - 1, y) = 8 THEN CheckFood = 1
  CASE 1
    IF POINT(x, y - 1) = 8 THEN CheckFood = 1
  CASE 2
    IF POINT(x + 1, y) = 8 THEN CheckFood = 1
  CASE 3
    IF POINT(x, y + 1) = 8 THEN CheckFood = 1
  END SELECT
END FUNCTION

FUNCTION CheckWall (direction AS INTEGER, x AS INTEGER, y AS INTEGER)
  SELECT CASE direction
  CASE 0
    check = POINT(x - 1, y)
    IF check = 4 OR check = 15 OR check = 5 THEN CheckWall = 1
  CASE 1
    check = POINT(x, y - 1)
    IF check = 4 OR check = 15 OR check = 5 THEN CheckWall = 1
  CASE 2
    check = POINT(x + 1, y)
    IF check = 4 OR check = 15 OR check = 5 THEN CheckWall = 1
  CASE 3
    check = POINT(x, y + 1)
    IF check = 4 OR check = 15 OR check = 5 THEN CheckWall = 1
  END SELECT
END FUNCTION

SUB EndGame (score AS INTEGER)
  SOUND 150, 7
  SLEEP (1)
  CLS
  PRINT "Peli loppui!"
  PRINT "Sait"; score; "pistettä"
  END
END SUB

SUB PauseGame
  LOCATE 1, 34
  PRINT "PAUSED"
  SLEEP (1)
  DO
  LOOP UNTIL INKEY$ <> ""
  LOCATE 1, 34
  PRINT "      "
END SUB